Metadata objects: constants, catalogs, documents, enumerations

In ordinary programming you create database tables, forms and menus by hand. In 1C you simply describe a metadata object — for example “Products catalog, attributes: Price, Unit” — and the platform builds the table, the list and item forms and the commands by itself. A configuration is assembled from such ready-made building blocks.

Constants and catalogs

A constant (Константа) stores a single value for the whole base: the company name, the main currency, whether VAT is used. A catalog (Справочник) is a list of items of the same kind: products, counterparties, employees, warehouses. Every catalog has standard attributes: Код (Code), Наименование (Description), ПометкаУдаления (DeletionMark) and Ссылка (Ref).

• Hierarchy: a catalog can be split into groups (Иерархия групп и элементов), which adds the Родитель (Parent) and ЭтоГруппа (IsFolder) attributes. For example “Drinks → Tea”.
• Owner (Владелец): one catalog can be subordinate to another, for example contracts belong to a counterparty.
• Attributes and tabular sections: your own fields (Price, Unit) and lists of rows (for example a product's barcodes).
• Predefined items are created in the Configurator and referred to by name in code: Справочники.Склады.Основной.

// Новый элемент справочника
НовыйТовар = Справочники.Товары.СоздатьЭлемент();
НовыйТовар.Наименование = "Çay 100 q";
НовыйТовар.Цена = 3.5;
НовыйТовар.Записать();

// Поиск и изменение существующего элемента
ТоварСсылка = Справочники.Товары.НайтиПоНаименованию("Çay 100 q");
Если Не ТоварСсылка.Пустая() Тогда
    ТоварОбъект = ТоварСсылка.ПолучитьОбъект();
    ТоварОбъект.Цена = 4;
    ТоварОбъект.Записать();
КонецЕсли;

// Константа
Валюта = Константы.ОсновнаяВалюта.Получить();

Documents

A document (Документ) records a business transaction that happens at a point in time: goods received, a sale, a payment. Its standard attributes are Номер (Number), Дата (Date), Проведен (Posted) and ПометкаУдаления. Numbers are assigned automatically and can, for example, restart every year. The document's key ability is posting (проведение): a posted document creates records in registers — we will study this in a separate lesson.

1. 1
   Add a document

   Документы → Добавить, name: ПриходТовара (goods receipt). The synonym becomes Приход товара automatically. Tick the Склад subsystem.

2. 2
   Create a tabular section

   On the Данные tab: Табличные части → Товары, columns: Товар (type СправочникСсылка.Товары), Количество, Цена, Сумма (Число).

3. 3
   Check it

   Press F5, create a new document in the Склад section and add a few rows to the tabular section. The platform built the form automatically — you did not draw any form.

Приход = Документы.ПриходТовара.СоздатьДокумент();
Приход.Дата = ТекущаяДатаСеанса();

НоваяСтрока = Приход.Товары.Добавить();
НоваяСтрока.Товар = Справочники.Товары.НайтиПоНаименованию("Çay 100 q");
НоваяСтрока.Количество = 10;
НоваяСтрока.Цена = 4;
НоваяСтрока.Сумма = НоваяСтрока.Количество * НоваяСтрока.Цена;

Приход.Записать();  // номер присвоится автоматически

Enumerations and other objects

An enumeration (Перечисление, Enum) is a fixed list whose values only the developer defines: payment types (cash, card), order statuses. In code: Перечисления.ВидыОплаты.Наличные. Users cannot add new values — that is the key difference from a catalog.